VBAでid属性からデータを抽出するためのサブルーチン「idValue」

VBAのIE(InternetExplorer)制御に便利なサブルーチンを紹介しています。

Function nameValue(objIE As InternetExplorer, _
                 idName As String, _
                 valueType As String, _
                 Optional pcType As String, _
                 Optional num As Byte) As String

  Dim objDoc As Object

  If pcType = "parent" Then
    
    Set objDoc = objIE.document.getElementById(idName).parentElement
        
  ElseIf pcType = "child" Then
  
    Set objDoc = objIE.document.getElementById(idName).Children(num)
        
  Else

    Set objDoc = objIE.document.getElementById(idName)
    
  End If

  With objDoc

    Select Case valueType

      Case "innerHTML"

        nameValue = .innerHTML

      Case "innerText"
             
        nameValue = .innerText
      
      Case "outerHTML"

        nameValue = .outerHTML

      Case "outerText"

        nameValue = .outerText

    End Select

  End With

End Function

Function idValue(objIE As InternetExplorer, _
                 idName As String, _
                 valueType As String, _
                 Optional pcType As String, _
                 Optional num As Byte) As String

こちらは戻り値を返すFunctionステートメントに引数を5つ設定しているidValueサブルーチンになります。こちらの構文と引数の内容は以下になります。尚、引数はすべて参照渡しで渡されます。

引数objIEは必須項目で、文書ドキュメントを抽出するnternetExplorerオブジェクトを指定します。InternetExplorerオブジェクトを引数に設定することで、複数のオブジェクトを処理することができます。

引数idNameは必須項目で、抽出するid属性の名前を文字列で指定します。間接的に親要素から抽出する場合には親要素のid属性の名前を、子要素から抽出する場合には子要素のid属性の名前を文字列で指定します。

以下の事例で言えば、div要素から間接的に指定する場合はid属性「idparent」を、span要素から間接的に指定する場合はid属性「idchild」を指定します。

こちらの詳細については、「文書ドキュメント取得の処理の考え方」を確認してください。

<div id="idparent">
<p>****</p>
<p>抽出したい<span id="idchild">要素</span></p>
<p>****</p>
</div>

引数valueTypeは必須項目で、データ取得のプロパティ名を文字列で指定します。データ取得のプロパティは「innerHTML」「innerText」「outerHTML」「outerText」の4つになります。

詳細については、「HTMLコードを取得する」を確認してください。

引数pcTypeは省略可能な項目で、間接的に親要素から抽出する場合には「parent」を、子要素から抽出する場合には「child」を文字列で指定します。「parent」を指定した場合はparentElementプロパティで、「child」を指定した場合はChildrenプロパティで、間接的に抽出する要素オブジェクトを取得します。

尚、抽出する要素オブジェクトにid属性が設定されている場合は、そのオブジェクトを直接取得するため引数pcTYpeは省略します。

引数numは省略可能な項目で、引数pcTypeで「child」を指定した場合のみChildrenプロパティの添え字を指定します。

Dim objDoc As Object

こちらは、変数宣言でメモリ領域を割り当てるDimステートメントを利用してオブジェクト変数objDocに「オブジェクト型(Object)」を変数宣言しています。

先に説明すると、データ型はオブジェクト型(Object)を利用せず、より具体的なデータ型を宣言するほうがよいとされています。理由としては、補助入力機能など利便性のよさなどが挙げられます。

こちらについては本来であれば、「HTMLParaElement型」または「HTMLDocument型」などを指定するのがよいのでしょうか処理速度の観点からいうと必ずしもよいというわけではなりません。

他にもいくつか検証したのですが、以下のようにHTML関連のデータ型を選択した場合とオブジェクト型(Object)ではどれもオブジェクト型(Object)を選択した方が処理速度が速い結果となりました。

ですので、こちらで解説している内容のほとんどはオブジェクト型(Object)を選択しています。特に変更してもらっても問題ありませんので、自由に変更してください。

  If pcType = "parent" Then
    
    Set objDoc = objIE.document.getElementById(idName).parentElement
        
  ElseIf pcType = "child" Then
  
    Set objDoc = objIE.document.getElementById(idName).Children(num)
        
  Else

    Set objDoc = objIE.document.getElementById(idName)
    
  End If

次に条件分岐ができるIf～Then～Elseステートメントを利用して抽出する要素オブジェクトを設定しています。引数pcTypeに「parent」を設定している場合は、getElementByIdメソッドを利用して子要素を取得してからparentElementプロパティで抽出する要素を取得します。

「child」を設定している場合は、getElementByIdメソッドを利用して親要素を取得してからChildrenプロパティで引数numを添え字に設定し、抽出する要素を取得します。

引数pcTypeを設定していない場合、getElementByIdメソッドに抽出する要素のid属性を設定して抽出する要素を取得します。

尚、取得する際はオブジェクトを参照するSetステートメントを利用してオブジェクト変数objDocに代入します。

  With objDoc

    Select Case valueType

      Case "innerHTML"

        idValue = .innerHTML

      Case "innerText"
             
        idValue = .innerText
      
      Case "outerHTML"

        idValue = .outerHTML

      Case "outerText"

        idValue = .outerText

    End Select

  End With

End Function

こちらでは、1つのオブジェクトに対して処理をまとめるWithステートメントのオブジェクト名にオブジェクト変数objDocを設定しています。次に複数の条件分岐を設定するSelect Caseステートメントを利用して引数valueTypeの設定値で条件分岐させています。

こちらでは、innerHTML・innerText・outerHTML・outerTextプロパティを利用して抽出する要素のどの部分の文書ドキュメントを抽出するかを選択しています。そして、取得した値を戻り値idValueに代入演算子で格納したら処理が完了します。