VBAで指定した要素が存在するかチェックするプロシージャ

トップページ
エクセルVBAでHTMLエレメント実践操作
指定した要素が存在するかﾁｪｯｸするﾌﾟﾛｼｰｼﾞｬ

指定した要素が存在するかチェック

前回は、文書ドキュメントの指定した要素が存在するかチェックする方法について解説しました。こちらは主にページ送りのチェックや待機処理などで利用されます。今回は、文書ドキュメントの指定した要素が存在するかチェックするサブルーチンの作成について解説していきます。

DOM(Document Object Model)とは
HTML(HyperText Markup Language)とは
タグと要素(エレメント)の違い
指定した要素が存在するかのチェックとは
利用するサブルーチン・プロパティ・メソッド・VBA関数について
指定した要素が存在するかチェックするサブルーチン「tagCheck」の解説
「tagCheck」を利用してa要素の「次へ」リンクが存在するかチェックするサンプルコード
- チェック対象のHTMLコード
- 解説
まとめ

DOM(Document Object Model)とは

DOMとは「Document Object Model」の略称で、html・head・body・p・aなどのHTMLドキュメント要素にアクセスして取得や操作ができる仕組みのことです。

以下はHTMLドキュメントをツリー構造に表したものでDOMツリーと呼ばれます。階層状のツリー構造でHTMLドキュメントを表現します。

HTML(HyperText Markup Language)とは

HTMLとは「HyperText Markup Language」の略称で、Webページを作成するために開発された言語です。世の中に公開されているWebページのほとんどがHTMLで作成されています。こちらのサイトもHTMLで作成されています。

HTMLは基本的に以下のような構成でできており「<タグ名>★テキスト★</タグ名>」が1つの要素(エレメント)になります。この中の特定の要素に対してデータの取得や操作を行っていきます。

<html>

 <head>

  <title>VBAのIE制御</title>

 </head>

 <body>

  <p>こちらはpタグのテキストです。</p>
  <a href="★リンクURL(アドレス)★">リンクのアンカーテキストです。</a>

 </body>

</html>

タグと要素(エレメント)の違い

HTML言語では、「タグ」と呼ばれる仕組みを利用して構築していきます。以下のイメージを確認すると分かりやすいと思いますが、タグとは「<」と「>」で構成されており、開始タグと終了タグまでの括りで1つの要素を形成します。

具体例で説明するとWebページのURL(アドレス)を表す「titleタグ」を利用して開始タグの「<title>」と終了タグの「</title>」で括り、タグの中の文字列が「要素内容」となります。こちらでは「VBAのIE制御入門」の文字列が要素内容となります。

そして、こちらの「開始タグ+要素内容+終了タグ」の全体を「要素」と呼びます。また、別名では「エレメント」と呼ばれますので、どちらも同じ意味であることを理解してください。

指定した要素が存在するかのチェックとは

まず、今回の「指定した要素が存在するかのチェック」がどのような場合に利用されるかについて説明します。例えばwebスクレイピングであるECサイトの商品一覧情報を抽出したい場合、ページの構成はどのようになっているかイメージできますか？

ほとんどのECサイトは一覧ページが複数ページにまたがっており、ページ送り(ページネーション)が設定されている形になります。「ページ送り」とは、次ページのリンクのことで商品一覧の上下どちらかにページ番号のリストを表示させるのが一般的です。

その中にはページ番号の両端に「前へ」「次へ」といったリンクも見かけることが多いと思いますが、こちらのクリック処理にキーワードのチェック機能が役に立ちます。

どういう事かと言うと商品一覧情報を抽出する場合はページの総数分をループ処理させるか、最終ページを判断して処理を終了させるかのどちらかになるかと思います。前者の場合は最終ページ番号を事前に取得する必要があり、後者の場合は最終ページを判断するチェックが必要となります。

この「最終ページを判断するチェック」に今回の処理を利用します。処理の手順は以下のような形になります。

①商品一覧ページを表示する。
②「次へ」のリンクが存在するかチェックする。
③存在する場合は「次へ」のリンクをクリックする。
④「次へ」のリンクが存在する限り②③を繰り返す。
⑤「次へ」のリンクが存在しない場合は処理を終了する。

このように処理をすれば最終ページを気にする必要がなく、簡単に商品一覧の情報を抽出することができます。また、他の利用方法としては私が実際に行っている処理を事例として紹介します。

「TinyPNG」というWebサービスはご存知でしょうか？こちらはPNGファイルを圧縮してくれるWebサービスで画像を圧縮するにはとても便利なサイトです。こちらの利用方法をまとめると以下のような処理になります。

①PNGファイルをブラウザにドラッグ＆ドロップする。
②ブラウザ上で圧縮処理が行われる。
③圧縮が完了するとdownloadリンクが表示される。
④downloadをクリックして圧縮したPNGファイルをダウンロードする。

といった流れになります。ただし、ファイル数が多い場合はファイルの数だけdownloadリンクをクリックしなければならない手間が発生します。もちろんこちらはエクセルVBAのIE制御で簡単に自動クリックすることができますが、そのタイミングが問題となります。

毎回処理するファイル数も異なり、環境によってはいつdownloadのリンクが表示されるかが分かりません。もちろん多めに調整して1分間処理を停止してからクリック処理をするということもできますが、それではあまりパフォーマンスがよくありません。

そこで、「指定した要素が存在するかのチェック」を利用します。具体的に説明すると全てのファイルが圧縮されると「Panda just saved you」という文言が表示されます。こちらの要素をチェック対象として「Panda just saved you」のキーワードが表示されるまでループ処理を行います。

そして、こちらが表示された時点でループ処理を解除し次の処理へ移ります。これによりリアルタイムで処理を行うことができます。このように「指定した要素が存在するかのチェック」は色々と便利な機能です。処理自体も特に難しくはないので是非覚えておきましょう

利用するサブルーチン・プロパティ・メソッド・VBA関数について

今回利用するサブルーチン・プロパティ・メソッド・VBA関数は以下になります。利用方法については処理の解説で行いますが、どのような機能を持っているのか簡単に目を通してください。

ieViewサブルーチン
ieCheckサブルーチン
Documentプロパティとは
getElementsByNameメソッドとは
getElementsByClassNameメソッドとは
getElementsByTagNameメソッドとは
outerHTMLプロパティとは
InStr関数とは
MsgBox関数とは

ieViewサブルーチンとは

ieViewサブルーチンは指定したURL(アドレス)をInternetExplorerで起動させ、Webページが完全に読み込まれるまで待機処理をするマクロです。

ieView("IEオブジェクト","表示させたいURL(アドレス)の文字列","IE表示・非表示の値[省略可]","Y位置の値[省略可]","X位置の値[省略可]","幅の値[省略可]","高さの値[省略可]")

ieView

ieCheckサブルーチンとは

ieCheckサブルーチンは指定したInternetExplorerオブジェクトのWebページが完全に読み込まれるまで待機処理をするマクロです。

ieCheck("IEオブジェクト")

ieCheck

Documentプロパティとは

InternetExplorerオブジェクトのDocumentプロパティはHTMLドキュメントのオブジェクトを返すプロパティです。これによりHTMLドキュメントを操作することができます。

objIE.document.プロパティ/メソッド

Documentプロパティ

GetElementsByNameメソッドとは

DocumentオブジェクトのGetElementsByNameメソッドはHTMLドキュメント内の指定したname属性の要素オブジェクトのコレクションを返すメソッドです。

objIE.document.GetElementsByName("name名")(添え字).プロパティ/メソッド

GetElementsByClassNameメソッドとは

DocumentオブジェクトのGetElementsByClassNameメソッドはHTMLドキュメント内の指定したclass属性の要素オブジェクトのコレクションを返すメソッドです。

objIE.document.GetElementsByClassName("class名")(添え字).プロパティ/メソッド

getElementsByTagNameメソッドとは

DocumentオブジェクトのgetElementsByTagNameメソッドはHTMLドキュメント内の指定したタグ名の要素オブジェクトのコレクションを返すメソッドです。

objIE.document.getElementsByTagName("タグ名")(添え字).プロパティ/メソッド

outerHTMLプロパティとは

要素オブジェクトのouterHTMLプロパティは指定した要素オブジェクトの要素タグとその中に含まれるHTMLコードを取得するプロパティです。

変数 = objIE.document.要素オブジェクト.outerHTML

赤文字がpタグのouterHTMLの取得範囲になります。

<p>pタグの<span class="colorRed">outerHTML</span>の取得範囲</p>

InStr関数とは

InStr関数はある文字列(string1)の中から指定した文字列(string2)を検索して最初に見つかった文字位置返すVBA関数です。

変数 = InStr(string1, string2)

InStr関数

MsgBox関数とは

MsgBox関数はダイアログボックスにメッセージとボタンを表示し、どのボタンが押されたかを示す整数型の数値を返します。

MsgBox "表示させる文字列"

MsgBox関数

指定した要素が存在するかチェックするサブルーチン「tagCheck」の解説

こちらは、指定した要素が存在するかチェックするサブルーチンになります。

Function tagCheck(objIE As InternetExplorer, _
                 methodType As String, _
                 elementName As String, _
                 keywords As String) As Boolean
 
  Dim objDoc  As Object, myDoc  As Object
  
  tagCheck = False

  Select Case methodType
        
    Case "name"
  
      Set objDoc = objIE.document.getElementsByName(elementName)
    
    Case "class"
  
      Set objDoc = objIE.document.getElementsByClassName(elementName)
    
    Case "tag"

      Set objDoc = objIE.document.getElementsByTagName(elementName)

  End Select

 
  For Each myDoc In objDoc

    If InStr(myDoc.outerHTML, keywords) > 0 Then
    
      tagCheck = True
      
      Exit For

    End If

  Next

End Function

それでは、VBAコードを１つずつ説明していきます。

Function tagCheck(objIE As InternetExplorer, _
                 methodType As String, _
                 elementName As String, _
                 keywords As String) As Boolean

こちらは戻り値を返すFunctionステートメントに引数を4つ設定しているtagCheckサブルーチンになります。こちらの構文と引数の内容は以下になります。尚、引数はすべて参照渡しで渡されます。

tagCheck("IEオブジェクト","メソッドタイプの文字列","メソッド引数の文字列","チェックするキーワード")

引数名	データ型	内容	値の事例	省略
構文	classValue(objIE,className,tagName,valueType)
objIE	InternetExplorer	InternetExplorerオブジェクトを指定します。	objIE, objIE2	×
methodType	String	要素を抽出するメソッドのタイプを文字列で指定します。getElementsByNameメソッドの場合は「name」を、getElementsByClassNameメソッドの場合は「class」を、getElementsByTagNameメソッドの場合は「tag」を指定します。	"name","class", "tag"	×
elementName	String	メソッドの引数を文字列で指定します。引数methodTypeに「name」を指定した場合はid名を、「class」を指定した場合はclass名を「tag」を指定した場合はタグ名を指定します。	"nametset", "classtest", "p"	×
keywords	String	チェックするキーワードを文字列で指定します。	"次へ"	×

引数objIEは必須項目で、文書ドキュメントを抽出するnternetExplorerオブジェクトを指定します。InternetExplorerオブジェクトを引数に設定することで、複数のオブジェクトを処理することができます。

引数methodTypeは必須項目で、要素を抽出するメソッドのタイプを文字列で指定します。getElementsByNameメソッドの場合は「name」を、getElementsByClassNameメソッドの場合は「class」を、getElementsByTagNameメソッドの場合は「tag」で指定します。

引数elementNameは必須項目で、メソッドの引数を文字列で指定します。引数methodTypeに「name」を指定した場合はid名を、「class」を指定した場合はclass名を「tag」を指定した場合はタグ名を指定します。

引数keywordsは必須項目で、チェックするキーワードを文字列で指定します。

Dim objDoc As Object, myDoc As Object

こちらは、変数宣言でメモリ領域を割り当てるDimステートメントを利用してオブジェクト変数objDoc,myDocに「オブジェクト型(Object)」を変数宣言しています。

先に説明すると、データ型はオブジェクト型(Object)を利用せず、より具体的なデータ型を宣言するほうがよいとされています。理由としては、補助入力機能など利便性のよさなどが挙げられます。

こちらについては本来であれば、「HTMLParaElement型」または「HTMLDocument型」などを指定するのがよいのでしょうか処理速度の観点からいうと必ずしもよいというわけではなりません。

他にもいくつか検証したのですが、以下のようにHTML関連のデータ型を選択した場合とオブジェクト型(Object)ではどれもオブジェクト型(Object)を選択した方が処理速度が速い結果となりました。

ですので、こちらで解説している内容のほとんどはオブジェクト型(Object)を選択しています。特に変更してもらっても問題ありませんので、自由に変更してください。

回数・処理	オブジェクト型(Object)	HTMLParaElement型	HTMLDocument型
1回目	27.3418秒	31.6074秒	31.9866秒
2回目	28.3105秒	34.0234秒	33.9478秒

  tagCheck = False

こちらでは戻り値tagaCheckに「False」を設定しています。引数keywordsのキーワードが見つからなかった場合はこちらの「False」を戻り値として返します。

  Select Case methodType

    Case "name"
  
      Set objDoc = objIE.document.getElementsByName(elementName)
    
    Case "class"
  
      Set objDoc = objIE.document.getElementsByClassName(elementName)
    
    Case "tag"

      Set objDoc = objIE.document.getElementsByTagName(elementName)

  End Select

こちらでは、複数の条件分岐を設定するSelect Caseステートメントを利用して引数methodTypeの設定値で条件分岐させています。

こちらでは、getElementsByName・getElementsByClassName・getElementsByTagNameメソッドの中からどのメソッドを利用して抽出する要素を取得するかを選択しています。

こちらの条件分岐は極力処理速度の遅いgetElementsByTagNameメソッドを利用しないための処理です。一意のキーワードの要素にname・class属性が設定されている場合は、getElementsByName・getElementsByClassNameメソッドを利用するようにしましょう。

  For Each myDoc In objDoc

   （処理省略）

  Next

こちらでは、For Each～Nextステートメントのコレクションに設定し、オブジェクト変数objDocを設定しています。これにより先ほど取得した要素数だけループ処理を行っています。

If InStr(myDoc.outerHTML, keywords) > 0 Then
    
      tagCheck = True
      
      Exit For

    End If

こちらでは、If～Then～Elseステートメントを利用して要素内の文書ドキュメントに引数keywordsのキーワードが含まれていないかチェックしています。

キーワードが含まれているかをチェックするには、指定したキーワードで最初に見つかった文字位置を返すInStr関数を利用しています。要素の文書ドキュメントに「次へ」のキーワードが含まれている場合は必ず「0」以上の値を返すので、比較演算子を利用して「0」以上の場合を条件式としています。

そして、キーワードが含まれている場合は戻り値tagCheckに「True」を設定します。チェックが完了するとループ処理をする必要がありませんので、ループ処理を回避するExit Forステートメントを利用してループから抜け出します。

「tagCheck」を利用してa要素の「次へ」リンクが存在するかチェックするサンプルコード

こちらのVBAコードは、tagCheckサブルーチンを利用してa要素の「次へ」リンクが存在するかチェックするマクロです。

Sub sample()

  Dim objIE  As InternetExplorer
  
  'IE(InternetExplorer)でテストページを起動する
  Call ieView(objIE, "http://www.vba-ie.net/code/all.html")
  
  'getElementsByNameメソッドでキーワードをチェックする
  If tagCheck(objIE, "name", "namelink", "次へ") = True Then
    
    MsgBox "name属性が「namelink」かつ要素内容が「次へ」への要素が見つかりました。"
  
  End If

  'getElementsByClassNameメソッドでキーワードをチェックする
  If tagCheck(objIE, "class", "classlink", "次へ") = True Then
    
    MsgBox "class属性が「classlink」かつ要素内容が「次へ」への要素が見つかりました。"
  
  End If
  
  'getElementsByTagNameメソッドでキーワードをチェックする
  If tagCheck(objIE, "tag", "a", "次へ") = True Then
    
    MsgBox "タグが「a」かつ要素内容が「次へ」への要素が見つかりました。"
  
  End If

End Sub

チェック対象のHTMLコード

解説

Sub sample()

  Dim objIE  As InternetExplorer

こちらはSubステートメントに引数の設定がないsampleプロシージャになります。まずは、変数宣言でメモリ領域を割り当てるDimステートメントを利用してオブジェクト変数objIEに「InternetExplorer型」を変数宣言しています。

  'IE(InternetExplorer)でテストページを起動する
  Call ieView(objIE, "http://www.vba-ie.net/code/all.html")

次に他のプロシージャを呼び出すCallステートメントを利用してieViewサブルーチンを呼び出しています。第一引数にはオブジェクト変数の「objIE」を第二引数には表示させるURL(アドレス)の「http://www.vba-ie.net/code/all.html」を設定しています。これによりInternetExplorerで本サイトのテストページが表示されます。

  'getElementsByNameメソッドで文書ドキュメントを抽出する
  If tagCheck(objIE, "name", "namelink", "次へ") = True Then
    
    MsgBox "name属性が「namelink」かつ要素内容が「次へ」への要素が見つかりました。"
  
  End If

こちらは、tagCheckサブルーチンを利用してname属性「namelink」で「次へ」のキーワードが含まれる要素をチェックしています。

VBAのIE制御でgetElementsByNameメソッドを利用してデータをチェックした結果

  'getElementsByClassNameメソッドで文書ドキュメントを抽出する
  If tagCheck(objIE, "class", "classlink", "次へ") = True Then
    
    MsgBox "class属性が「classlink」かつ要素内容が「次へ」への要素が見つかりました。"
  
  End If

こちらは、tagCheckサブルーチンを利用してclass属性「classlink」で「次へ」のキーワードが含まれる要素をチェックしています。

VBAのIE制御でgetElementsByClassNameメソッドを利用してデータをチェックした結果

'getElementsByTagNameメソッドで文書ドキュメントを抽出する
  If tagCheck(objIE, "tag", "a", "次へ") = True Then
    
    MsgBox "タグが「a」かつ要素内容が「次へ」への要素が見つかりました。"
  
  End If

こちらは、tagCheサブルーチンを利用してaタグで「次へ」のキーワードが含まれる要素をチェックしています。

VBAのIE制御でgetElementsByTagNameメソッドを利用してデータをチェックした結果

こちらは3つとも同じ処理になります。どのメソッドを利用しても結果は変わりませんが、処理速度を計測すると以下のような結果になります。

回数・処理	getElementsByName	getElementsByClassName	getElementsByTagName
1回目	14.5273秒	14.7188秒	30.8867秒	2回目	14.5078秒	14.6211秒	30.7891秒

getElementsByTagNameメソッドを利用すると処理速度が他に比べて遅くなるので、getElementsByTagNameメソッド以外で取得できる場合はそちらを利用しましょう。

ただし、何度も説明していますが、多くの処理を行うwebスクレイピングの場合に有効ですので、ログイン処理や短時間で済む処理の場合は簡単な方法を選択してください。

まとめ

今回は、文書ドキュメントの指定した要素が存在するかチェックするサブルーチンの作成について解説しました。こちらは3つのメソッドを利用しましたが、getElementsByTagNameメソッドは処理速度が遅くなるので極力他のメソッドを利用して処理しましょう。次回は、指定した要素のリンクURLを抽出する方法について解説していきます。

次の記事：エクセルVBAで指定した要素のリンクURLを抽出する >>