VBAのIE制御

「情報収集に役立つサブルーチン集」では、ネット上のデータ収集やサイト操作など様々な利用方法の中で役に立つサブルーチンを紹介していきます。
まずはデータ収集でリスト化する際に利用頻度の高い最終行（列）の取得について解説していきます。

最終行（列）取得のサブルーチン

Function maxRC(Optional sheetName As String = "mySheet", _
　　　　　　　 Optional rcNo As Variant = 1, _
　　　　　　　 Optional addRC As Integer = 0, _
　　　　　　　 Optional typeRC As String = "R") As Long

    If sheetName = "mySheet" Then
        sheetName = ActiveSheet.Name
    End If
    
    If typeRC = "R" Then
        maxRC = Sheets(sheetName).Cells(Rows.Count, rcNo).End(xlUp).row + addRC
    ElseIf typeRC = "C" Then
        maxRC = Sheets(sheetName).Cells(rcNo, Columns.Count).End(xlToLeft).Column + addRC
    End If

End Function

※ドラッグ(スワイプ)すると全体を確認できます。

最終行（列）取得のマクロ

Sub sample()

  Dim objIE  As InternetExplorer
　Dim r As Integer, c As Integer

  'テスト用フォームページを表示
  Call ieView(objIE, "http://www.vba-ie.net/code/test.html")
  
  '最終行取得（Y方向）
  r = maxRC("リスト", 1, 1)

  'h1要素のテキストデータ取得
  Sheets("リスト").Cells(r, 1) = "h1要素テキスト：" & tagValue(objIE, "h1", "", "outerHTML")
  'p要素のテキストデータ取得
  Sheets("リスト").Cells(r + 1, 1) = "p要素テキスト：" & tagValue(objIE, "p", "p-value", "innerText")
  
  '最終列取得（X方向）
  c = maxRC("リスト", 1, 1, "C")

  'h1要素のテキストデータ取得
  Sheets("リスト").Cells(1, c) = "h1要素テキスト：" & tagValue(objIE, "h1", "", "outerHTML")
  'p要素のテキストデータ取得
  Sheets("リスト").Cells(1, c + 1) = "p要素テキスト：" & tagValue(objIE, "p", "p-value", "innerText")

End Sub

※ドラッグ(スワイプ)すると全体を確認できます。

実行結果

今回は、値を取得するために戻り値が必要となりますのでfunctionマクロで対応しています。引数は以下の4つが設定されています。

こちらは、全て任意項目となります。
「sheetName」はシート名文字列を入力しますが、処理するシートが現在開いているシートの場合は、初期値で現在開いているシート名を取得しますので、未入力で大丈夫です。
「rcNo」は対象の行・列番号（文字列）で、例えばD列目の最終行を取得したい場合は「4」もしくは「"D"」を入力します。初期値では「1」が設定されています。
行をチェックする場合は、行番号を入力すれば簡単に取得できますが、列をチェックする場合は、通常アルファベット表示のため、何番目の列か分かりづらいです。
そこで、列番号でも列文字列でも対応できるように「Variant型」で宣言させています。
これにより「"D"」など列文字列でも対応できますので、何番目の列かを気にする必要はありません。
「addRC」には、最終行数に加える行数になります。例えばデータをループ処理する場合は、最終行を取得して全てのデータを処理させますが、データは定期的に抽出する場合は、既存データに書き足しで抽出します。その際に最終行から1行プラスで加えておけば、常に既存データの書き足しを行えます。
初期値は「0」設定されています。
「typeRC」は行・列どちらを取得するかの判断をするためのものです。「R」を指定すれば最終行を「C」を指定すれば最終列を取得します。初期値は「R」で設定されています。

それでは、1つずつコードを見ていきましょう。

If sheetName = "mySheet" Then
　sheetName = ActiveSheet.Name
End If

※ドラッグ(スワイプ)すると全体を確認できます。

sheetNameが設定されていれば指定したシート名をsheetNameに代入し、されていない場合は現在開いているシートがsheetNameに代入されます。

If typeRC = "R" Then
　maxRC = Sheets(sheetName).Cells(Rows.Count, rcNo).End(xlUp).row + addRC
ElseIf typeRC = "C" Then
　maxRC = Sheets(sheetName).Cells(rcNo, Columns.Count).End(xlToLeft).Column + addRC
End If

※ドラッグ(スワイプ)すると全体を確認できます。

typeRCが「R」の場合は最終行を「C」の場合は最終列を取得しています。
また、addRCが設定されていた場合は、+α行（列）を追加します。

ここまでがサブルーチンの中身になりますので、実行マクロの内容も見ていきましょう。

'最終行取得（Y方向）
r = maxRC("リスト", 1, 1)

'h1要素のテキストデータ取得
Sheets("リスト").Cells(r, 1) = "h1要素テキスト：" & tagValue(objIE, "h1", "", "outerHTML")

'p要素のテキストデータ取得
Sheets("リスト").Cells(r + 1, 1) = "p要素テキスト：" & tagValue(objIE, "p", "p-value", "innerText")

※ドラッグ(スワイプ)すると全体を確認できます。

こちらでは、まず「リスト」シートの1列目の最終行数を取得し、+1加えた数値をrに格納していますので、今回は1行目が見出しであったためr=2となります。
そして、cells(2, 1)にh1要素をcells(3, 1)にp要素のテキストを入力しています。

'最終列取得（X方向）
c = maxRC("リスト", 1, 1, "C")

'h1要素のテキストデータ取得
Sheets("リスト").Cells(1, c) = "h1要素テキスト：" & tagValue(objIE, "h1", "", "outerHTML")

'p要素のテキストデータ取得
Sheets("リスト").Cells(1, c + 1) = "p要素テキスト：" & tagValue(objIE, "p", "p-value", "innerText")

※ドラッグ(スワイプ)すると全体を確認できます。

こちらは「リスト」シートの1行目の最終列数を取得し、+1加えた数値をcに格納していますので、今回は2列目が見出しであったためc=3となります。
そして、cells(1, 3)にh1要素をcells(1, 4)にp要素のテキストを入力しています。

maxRCサブルーチンは非常によく利用される機能ですので、是非活用してください。