class属性を指定して特定の文書ドキュメントを抽出

<< エクセルVBAでname属性を指定して文書ドキュメントを抽出するサブルーチン ：前の記事

前回は、name属性を指定して文書ドキュメントを抽出するサブルーチンの作成について解説しました。こちらはname属性とタグ名の組み合わせが一意の場合に有効な方法です。

今回は、「文書ドキュメント取得の処理の考え方」で紹介した処理でclass属性を指定して特定の文書ドキュメントを簡単に抽出できるサブルーチンの作成について解説していきます。

目次

DOM(Document Object Model)とは

DOMとは「Document Object Model」の略称で、html・head・body・p・aなどのHTMLドキュメント要素にアクセスして取得や操作ができる仕組みのことです。

以下はHTMLドキュメントをツリー構造に表したものでDOMツリーと呼ばれます。階層状のツリー構造でHTMLドキュメントを表現します。

DOMツリー

HTML(HyperText Markup Language)とは

HTMLとは「HyperText Markup Language」の略称で、Webページを作成するために開発された言語です。世の中に公開されているWebページのほとんどがHTMLで作成されています。こちらのサイトもHTMLで作成されています。

HTMLは基本的に以下のような構成でできており「<タグ名>★テキスト★</タグ名>」が1つの要素(エレメント)になります。この中の特定の要素に対してデータの取得や操作を行っていきます。

<html>

 <head>

  <title>VBAのIE制御</title>

 </head>

 <body>

  <p>こちらはpタグのテキストです。</p>
  <a href="★リンクURL(アドレス)★">リンクのアンカーテキストです。</a>

 </body>

</html>

※ドラッグ(スワイプ)すると全体を確認できます。

タグと要素(エレメント)の違い

HTML言語では、「タグ」と呼ばれる仕組みを利用して構築していきます。以下のイメージを確認すると分かりやすいと思いますが、タグとは「<」と「>」で構成されており、開始タグと終了タグまでの括りで1つの要素を形成します。

タグと要素の違い

具体例で説明するとWebページのURL(アドレス)を表す「titleタグ」を利用して開始タグの「<title>」と終了タグの「</title>」で括り、タグの中の文字列が「要素内容」となります。こちらでは「VBAのIE制御入門」の文字列が要素内容となります。

そして、こちらの「開始タグ+要素内容+終了タグ」の全体を「要素」と呼びます。また、別名では「エレメント」と呼ばれますので、どちらも同じ意味であることを理解してください。

利用するサブルーチン・プロパティ・メソッド・VBA関数について

今回利用するサブルーチン・プロパティ・メソッド・VBA関数は以下になります。利用方法については処理の解説で行いますが、どのような機能を持っているのか簡単に目を通してください。

ieViewサブルーチンとは

ieViewサブルーチンは指定したURL(アドレス)をInternetExplorerで起動させ、Webページが完全に読み込まれるまで待機処理をするマクロです。

ieView("IEオブジェクト","表示させたいURL(アドレス)の文字列","IE表示・非表示の値[省略可]","Y位置の値[省略可]","X位置の値[省略可]","幅の値[省略可]","高さの値[省略可]")
ieView

ieCheckサブルーチンとは

ieCheckサブルーチンは指定したInternetExplorerオブジェクトのWebページが完全に読み込まれるまで待機処理をするマクロです。

ieCheck("IEオブジェクト")
ieCheck

Documentプロパティとは

InternetExplorerオブジェクトのDocumentプロパティはHTMLドキュメントのオブジェクトを返すプロパティです。これによりHTMLドキュメントを操作することができます。

objIE.document.プロパティ/メソッド
Documentプロパティ

GetElementsByClassNameメソッドとは

DocumentオブジェクトのGetElementsByClassNameメソッドはHTMLドキュメント内の指定したclass属性の要素オブジェクトのコレクションを返すメソッドです。

objIE.document.GetElementsByClassName("class名")(添え字).プロパティ/メソッド

outerHTMLプロパティとは

要素オブジェクトのouterHTMLプロパティは指定した要素オブジェクトの要素タグとその中に含まれるHTMLコードを取得するプロパティです。

変数 = objIE.document.GetElementsByClassName("class名")(添え字).outerHTML

赤文字がpタグのouterHTMLの取得範囲になります。

<p>pタグの<span class="colorRed">outerHTML</span>の取得範囲</p>

innerHTMLプロパティとは

要素オブジェクトのinnerHTMLプロパティは指定した要素オブジェクトの要素タグの間に含まれるHTMLコードを取得するプロパティです。指定した要素オブジェクトの要素タグは含まれません。

変数 = objIE.document.GetElementsByClassName("class名")(添え字).innerHTML

赤文字がpタグのinnerHTMLの取得範囲になります。

<p>pタグの<span class="colorRed">innerHTML</span>の取得範囲</p>

outerTextプロパティとは

要素オブジェクトのouterHTMLプロパティは指定した要素オブジェクトの要素内のテキスト部分のHTMLコードを取得するプロパティです。

変数 = objIE.document.GetElementsByClassName("class名")(添え字).outerText

赤文字がpタグのouterTextの取得範囲になります。

<p>pタグの<span class="colorRed">outerText</span>の取得範囲</p>

innerTextプロパティとは

要素オブジェクトのouterHTMLプロパティは指定した要素オブジェクトの要素内のテキスト部分のHTMLコードを取得するプロパティです。

変数 = objIE.document.GetElementsByClassName("class名")(添え字).innerText

赤文字がpタグのouterTextの取得範囲になります。

<p>pタグの<span class="colorRed">outerText</span>の取得範囲</p>

nodeNameプロパティとは

要素オブジェクトのnodeNameプロパティは指定した要素のタグ(ノード)名を取得するプロパティです。

変数 = objIE.document.GetElementsByClassName("class名")(添え字).nodeName

LCase関数とは

LCase関数はアルファベットの大文字を小文字に変換するVBA関数です。

変数 = LCase("小文字に変換させる文字列")
LCase関数

MsgBox関数とは

MsgBox関数はダイアログボックスにメッセージとボタンを表示し、どのボタンが押されたかを示す整数型の数値を返します。

MsgBox "表示させる文字列"
MsgBox関数

getElementsByClassNameメソッドを利用した特定の文書ドキュメントを抽出するサブルーチン「classValue」の解説

こちらは、getElementsByClassNameメソッドを利用した特定の文書ドキュメントを抽出するサブルーチンになります。

Function classValue(objIE As InternetExplorer, _
                 className As String, _
                 tagName As String, _
                 valueType As String) As String


  For Each objDoc In objIE.document.getElementsByClassName(className)

    With objDoc

      If LCase(.nodeName) = tagName Then
    
        Select Case valueType

          Case "innerHTML"

            classValue = .innerHTML

          Case "innerText"
             
            classValue = .innerText
      
          Case "outerHTML"
 
            classValue = .outerHTML

          Case "outerText"

            classValue = .outerText

        End Select

        Exit For

      End If
    
    End With

  Next

End Function

※ドラッグ(スワイプ)すると全体を確認できます。

それでは、VBAコードを１つずつ説明していきます。

Function classValue(objIE As InternetExplorer, _
                 className As String, _
                 tagName As String, _
                 valueType As String) As String

※ドラッグ(スワイプ)すると全体を確認できます。

こちらは戻り値を返すFunctionステートメントに引数を4つ設定しているclassValueサブルーチンになります。こちらの構文と引数の内容は以下になります。尚、引数はすべて参照渡しで渡されます。

classValue("IEオブジェクト","class属性の名前","タグ(ノード)の名前","データ取得のプロパティ名")
構文classValue(objIE,className,tagName,valueType)
引数名データ型内容値の事例初期値省略
objIEInternetExplorerInternetExplorerオブジェクトを指定します。objIE,
objIE2		×
classNameString抽出するclass属性の名前を文字列で指定します。"classtest2"×
tagNameString抽出するタグ(ノード)の名前を文字列(小文字)で指定します。"p","a","li"×
valueTypeStringデータ取得のプロパティ名を文字列で指定します。データ取得のプロパティは「innerHTML」「innerText」「outerHTML」「outerText」の4つになります。詳細については、「HTMLコードを取得する」を参照してください。"innerHTML",
"innerText",
"outerHTML",
"outerText"		×

引数objIEは必須項目で、文書ドキュメントを抽出するnternetExplorerオブジェクトを指定します。InternetExplorerオブジェクトを引数に設定することで、複数のオブジェクトを処理することができます。

引数classNameは必須項目で、抽出するclass属性の名前を文字列で指定します。

引数tagNameは必須項目で、抽出するタグ(ノード)の名前を文字列(小文字)で指定します。

尚、引数classNameと引数tagNameの組み合わせは「一意」の要素を選択する必要があります。「一意」というのは、他に同じものがなく1つしかないことを指します。

class属性はページ内で同じ名前のものを何度でも利用してもよいことになっています。仮に同じclass属性が存在した場合は、どちらかを判断するために更に処理が必要となりますので、ここでは1つしかない組み合わせを選択します。

以下の事例で言えばclass属性「classtest2」の要素はいくつか存在しますが、class属性「classtest2」のp要素は1つしか存在しませんので、class属性「classtest2」のp要素は「一意」と判断します。

こちらの詳細については、「文書ドキュメント取得の処理の考え方」を確認してください。

<p class="classtest1">****</p>
<div class="classtest2">****</div>
<div class="classtest2">****</div>
<p class="classtest2">抽出したい要素class</p>
<p class="classtest1">****</p>

引数valueTypeは必須項目で、データ取得のプロパティ名を文字列で指定します。データ取得のプロパティは「innerHTML」「innerText」「outerHTML」「outerText」の4つになります。

詳細については、「HTMLコードを取得する」を確認してください。

  For Each objDoc In objIE.document.getElementsByClassName(className)

   （処理省略）

  Next

※ドラッグ(スワイプ)すると全体を確認できます。

こちらでは、getElementsByClassNameメソッドに「引数classNmae」を設定して指定したclass属性の要素コレクションを取得しています。こちらをFor Each～Nextステートメントのコレクションに設定し、指定したclass属性の要素数だけループ処理を行っています。

    With objDoc

      If LCase(.nodeName) = tagName Then
    
        Select Case valueType

          Case "innerHTML"

            classValue = .innerHTML

          Case "innerText"
             
            classValue = .innerText
      
          Case "outerHTML"
 
            classValue = .outerHTML

          Case "outerText"

            classValue = .outerText

        End Select

        Exit For

      End If
    
    End With

※ドラッグ(スワイプ)すると全体を確認できます。

こちらではまず、1つのオブジェクトに対して処理をまとめるWithステートメントのオブジェクト名に「objDoc」を設定しています。こちらは先ほど取得したclass属性の要素コレクションのオブジェクトになります。

次にIf～Then～Elseステートメントを利用して指定したnameid属性のタグ(ノード)の名前が引数tagNameの場合に要素を抽出します。

タグ(ノード)の名前を取得するにはnodeNameプロパティを利用しますが、LCase関数でタグ(ノード)の名前を小文字に変換しています。ここまで確認した中ではnodeNameプロパティは大文字で返すのですが、イレギュラーを排除するために念のため小文字に変換しています。

そして複数の条件分岐を設定するSelect Caseステートメントを利用して引数valueTypeの設定値で条件分岐させています。

こちらでは、innerHTML・innerText・outerHTML・outerTextプロパティを利用して抽出する要素のどの部分の文書ドキュメントを抽出させるかを選択しています。そして、取得した値を戻り値classValueに代入演算子で格納したら処理が完了します。

それでは、次にこちらのサブルーチンを利用してテストページのclass属性「classtest2」のp要素の文書ドキュメント取得してみましょう。

「classValue」を利用して特定の文書ドキュメントを抽出するサンプルコード

こちらのVBAコードは、classValueサブルーチンを利用してclass属性「classtest2」のp要素の文書ドキュメントを取得するマクロです。

Sub sample()

  Dim objIE  As InternetExplorer
  
  'IE(InternetExplorer)でテストページを起動する
  Call ieView(objIE, "http://www.vba-ie.net/code/all.html")
  
  '指定したclass属性の文書ドキュメントを抽出する
  MsgBox classValue(objIE, "classtest2", "p", "innerText")


End Sub

※ドラッグ(スワイプ)すると全体を確認できます。

取得対象のHTMLコード

<p class="classtest1">****</p>
<div class="classtest2">****</div>
<div class="classtest2">****</div>
<p class="classtest2">抽出したい要素class</p>
<p class="classtest1">****</p>

解説

Sub sample()

  Dim objIE  As InternetExplorer

※ドラッグ(スワイプ)すると全体を確認できます。

こちらはSubステートメントに引数の設定がないsampleプロシージャになります。 まずは、変数宣言でメモリ領域を割り当てるDimステートメントを利用してオブジェクト変数objIEに「InternetExplorer型」を変数宣言しています。

  'IE(InternetExplorer)でテストページを起動する
  Call ieView(objIE, "http://www.vba-ie.net/code/all.html")

※ドラッグ(スワイプ)すると全体を確認できます。

次に他のプロシージャを呼び出すCallステートメントを利用してieViewサブルーチンを呼び出しています。第一引数にはオブジェクト変数の「objIE」を第二引数には表示させるURL(アドレス)の「http://www.vba-ie.net/code/all.html」を設定しています。これによりInternetExplorerで本サイトのテストページが表示されます。

  '指定したclass属性の文書ドキュメントを抽出する
  MsgBox classValue(objIE, "classtest2", "p", "innerText")

※ドラッグ(スワイプ)すると全体を確認できます。

こちらは、classValueサブルーチンを利用してclass属性「classtest2」のp要素の文書ドキュメントを抽出しています。

VBAのIE制御でgetElementsByClassNameメソッドを利用してデータを抽出した結果

まとめ

今回は、class属性を指定して文書ドキュメントを抽出するサブルーチンの作成について解説しました。こちらはclass属性とタグ名の組み合わせが一意の場合に有効な方法です。次回は、一意のキーワードを指定して文書ドキュメントを抽出するサブルーチンの作成について解説していきます。

次の記事： エクセルVBAで一意のキーワードを指定して文書ドキュメントを抽出するサブルーチン >>

Excel VBAでIEを思いのままに操作できるプログラミング術 Excel 2013/2010/2007/2003対応

IEのデータ収集＆自動操作のプログラミング本はこの1冊だけ！IEの起動やポップアップウィンドウ、表示を制御する基本的なコードはもちろん、テキストボックスやラジオボタン、表、ハイパーリンクなどのHTML部品を制御する方法など、自動操作に欠かせないノウハウを丁寧に解説。

VBAのIE制御についてのQ&A掲示板

↑VBAのIE操作で分からない事があればこちらの掲示板よりご質問ください。

ExcelのVBA初心者入門

↑こちらはVBAをマスターできるよう初心者向けのエクセルVBA入門コンテンツになります。

目次

IE制御の準備

IE制御の基本操作

IE制御の基本操作一覧(16)

HTMLエレメント基本操作

HTMLエレメント基本操作一覧(16)

HTMLエレメント実践操作

HTMLフォーム基本操作

HTMLフォーム基本操作一覧(16)

HTMLフレームの基本操作

HTMLフレームの基本操作一覧(8)

IE制御の応用編

IE制御の応用編一覧(7)

IE操作に便利なツール

こちらでは、これまでに紹介したIE(InternetExplorer)操作で便利な機能をツール化しています。無償でダウンロードできますので、目的に合わせたご利用ください。

IEのメソッド・プロパティ

こちらでは、IE(InternetExplorer)オブジェクトのメソッド・プロパティをまとめています。

IE操作のVBA関数

こちらでは、エクセルVBAのIE(InternetExplorer)操作で利用されたVBA関数をまとめています。

IE操作のステートメント

こちらでは、エクセルVBAのIE(InternetExplorer)操作で利用されたステートメントをまとめています。ExcelのVBAで基本的な部分になりますので、しっかり理解しましょう。

IE制御のVBAコード

こちらでは、これまでに作成したIE(InternetExplorer)操作で役立つサブルーチンをまとめています。
全てをコピーする必要はありませんが、目的に合わせたサブルーチンをご利用ください。

役立つVBAコード

役立つVBAコード一覧(23)

▲