画像やPDFファイルなどをダウンロード

<< エクセルVBAで画像をダウンロードして保存する ：前の記事

前回は画像をダウンロードして保存する方法について解説しました。IEを開いてから画像URLを取得する方法を紹介しましたが、取得済みの画像URL一覧がある場合は指定した回数同じ処理を繰り返すFor～Nextステートメントなどを利用して一括ダウンロードすることも可能です。今回は、ファイルをダウンロードして保存するサブルーチンの作成について解説していきます。

こちらでは画像データだけでなく、PDFファイルやエクセル・ワードファイルなど様々なファイルに対応した方法になります。

目次

DOM(Document Object Model)とは

DOMとは「Document Object Model」の略称で、html・head・body・p・aなどのHTMLドキュメント要素にアクセスして取得や操作ができる仕組みのことです。

以下はHTMLドキュメントをツリー構造に表したものでDOMツリーと呼ばれます。階層状のツリー構造でHTMLドキュメントを表現します。

DOMツリー

HTML(HyperText Markup Language)とは

HTMLとは「HyperText Markup Language」の略称で、Webページを作成するために開発された言語です。世の中に公開されているWebページのほとんどがHTMLで作成されています。こちらのサイトもHTMLで作成されています。

HTMLは基本的に以下のような構成でできており「<タグ名>★テキスト★</タグ名>」が1つの要素(エレメント)になります。この中の特定の要素に対してデータの取得や操作を行っていきます。


<html>

 <head>

  <title>VBAのIE制御</title>

 </head>

 <body>

  <p>こちらはpタグのテキストです。</p>
  <a href="★リンクURL★">リンクのアンカーテキストです。</a>

 </body>

</html>

※ドラッグ(スワイプ)すると全体を確認できます。

タグと要素(エレメント)の違い

HTML言語では、「タグ」と呼ばれる仕組みを利用して構築していきます。以下のイメージを確認すると分かりやすいと思いますが、タグとは「<」と「>」で構成されており、開始タグと終了タグまでの括りで1つの要素を形成します。

タグと要素の違い

具体例で説明するとWebページのタイトルを表す「titleタグ」を利用して開始タグの「<title>」と終了タグの「</title>」で括り、タグの中の文字列が「要素内容」となります。こちらでは「VBAのIE制御入門」の文字列が要素内容となります。

そして、こちらの「開始タグ+要素内容+終了タグ」の全体を「要素」と呼びます。また、別名では「エレメント」と呼ばれますので、どちらも同じ意味であることを理解してください。

利用するサブルーチン・プロパティ・VBA関数について

今回利用するサブルーチン・プロパティ・VBA関数は以下になります。

ieViewサブルーチンとは

ieViewサブルーチンは指定したURLをInternetExplorerで起動させ、Webページが完全に読み込まれるまで待機処理をするマクロです。

ieView("IEオブジェクト","表示させたいURLの文字列","IE表示・非表示の値[省略可]","Y位置の値[省略可]","X位置の値[省略可]","幅の値[省略可]","高さの値[省略可]")
ieView

ieCheckサブルーチンとは

ieCheckサブルーチンは指定したInternetExplorerオブジェクトのWebページが完全に読み込まれるまで待機処理するマクロです。

ieCheck("IEオブジェクト")
ieCheck

srcValueサブルーチンとは

srcValueサブルーチンは指定したimg要素の画像URLを抽出するマクロです。

srcValue("IEオブジェクト","抽出するimg要素の一意のキーワード")
srcValue

linkValueサブルーチンとは

linkValueサブルーチンは指定したa要素のリンクURLを抽出するマクロです。

linkValue("IEオブジェクト","抽出するa要素の一意のキーワード")
linkValue

Pathプロパティとは

Pathプロパティは指定されたオブジェクトの絶対パスを文字列で返すプロパティです。パス末尾の円記号(\)とオブジェクト名は含みません。

オブジェクト(アプリケーション).Path
Pathプロパティ

Windows APIとは

API(Application Programming Interface)は、アプリケーションからOSやプログラム言語を操作するためのライブラリです。このAPIを利用することでファイル制御やウインドウ制御などを行うことが出来ます。また、Windows APIはMicrosoft WindowsのAPIのことで、Windowsのバージョン毎に拡張されており16ビットは「Win16 API」32ビットは「Win32 API」と呼ばれます。

URLDownloadToFile関数とは

Windows APIのURLDownloadToFile関数は、インターネット上のファイル(画像ファイル、pdfファイルなど）をダウンロードするAPI関数です。

result = URLDownloadToFile(0, "画像ファイルURL", "画像保存先", 0, 0)

DeleteUrlCacheEntry関数とは

Windows APIのDeleteUrlCacheEntry関数は、指定したファイルのキャッシュを削除するAPI関数です。

DeleteUrlCacheEntry("キャッシュを削除するファイルのURL")

Mid関数とは

Mid関数は文字列から指定した文字数分の文字列を返します。

変数 = Mid("抽出する文字列","抽出する先頭位置")
Mid関数

InStrRev関数とは

InStr関数はある文字列(string1)の中から指定した文字列(string2)を後ろから検索して最初に見つかった文字位置を返します。

変数 = InStrRev(string1, string2)
InStrRev関数

MsgBox関数とは

MsgBox関数はダイアログボックスにメッセージとボタンを表示し、どのボタンが押されたかを示す整数型の数値を返します。

MsgBox "表示させる文字列"
MsgBox関数

指定したファイルをダウンロードするサブルーチン「fileDL」の解説

こちらは、指定したファイルをダウンロードするサブルーチンになります。

Declare Function URLDownloadToFile Lib "urlmon" Alias _
    "URLDownloadToFileA" (ByVal pCaller As Long, _
    ByVal szURL As String, _
    ByVal szFileName As String, _
    ByVal dwReserved As Long, _
    ByVal lpfnCB As Long) As Long

Declare Function DeleteUrlCacheEntry Lib "wininet" _
    Alias "DeleteUrlCacheEntryA" (ByVal lpszUrlName As String) As Long

Sub fileDL(objIE As InternetExplorer, _
　　　　　 tagStr As String, _
　　　　　 saveFolder As String, _
　　　　　 Optional fileDLType As String = "img")

　Dim fileURL As String, fileName As String, savePath As String
　Dim cacheDel As Long, result As Long
    
　'ファイルURL取得
　If fileDLType = "img" Then
　　fileURL = srcValue(objIE, tagStr)
　Else
　　fileURL = linkValue(objIE, tagStr)
　End If
    
  'ファイルチェック
  If fileURL = "" Then
    MsgBox "ファイルURLを取得できませんでした。"
    Exit Sub
  End If
    
　'ファイル名
　fileName = Mid(fileURL, InStrRev(fileURL, "/") + 1)
    
　'ファイル保存先(+画像ファイル名）
　savePath = ActiveWorkbook.Path & "\" & saveFolder & "\" & fileName
    
　'キャッシュクリア
　cacheDel = DeleteUrlCacheEntry(fileURL)
    
　'ファイルをダウンロード
　result = URLDownloadToFile(0, fileURL, savePath, 0, 0)
    
　If result <> 0 Then
　　MsgBox "ダウンロードに失敗しました。"
　End If

End Sub

※ドラッグ(スワイプ)すると全体を確認できます。

それでは、VBAコードを１つずつ説明していきます。

Declare Function URLDownloadToFile Lib "urlmon" Alias _
    "URLDownloadToFileA" (ByVal pCaller As Long, _
    ByVal szURL As String, _
    ByVal szFileName As String, _
    ByVal dwReserved As Long, _
    ByVal lpfnCB As Long) As Long

※ドラッグ(スワイプ)すると全体を確認できます。

まず、画像をダウンロードするWindows APIのURLDownloadToFile関数を使用できるようにAPIの宣言をします。宣言する場合は、宣言セクション内に記述します。宣言ステートメントは、最初のプロシージャ宣言の前に配置する必要がありますので、一番上に記述してください。

Declare Function DeleteUrlCacheEntry Lib "wininet" _
    Alias "DeleteUrlCacheEntryA" (ByVal lpszUrlName As String) As Long

※ドラッグ(スワイプ)すると全体を確認できます。

次に画像のキャッシュを削除するWindows APIのDeleteUrlCacheEntry関数を使用できるようにこちらもAPIの宣言をします。画像をダウンロードする際にキャッシュが存在するとキャッシュから読み込むので、最新の画像をダウンロードするためにキャッシュを削除してからダウンロードを行います。

Sub fileDL(objIE As InternetExplorer, _
　　　　　 tagStr As String, _
　　　　　 saveFolder As String, _
　　　　　 Optional fileDLType As String = "img")

※ドラッグ(スワイプ)すると全体を確認できます。

こちらはSubステートメントに引数を4つ設定しているfileDLサブルーチンになります。こちらの構文と引数の内容は以下になります。尚、引数はすべて参照渡しで渡されます。

fileDL("IEオブジェクト","タグ内の一意のキーワード文字列","ファイル保存先のフォルダ文字列","ダウンロードするファイルの種類文字列[省略可]")
構文fileDL(objIE,tagStr,saveFolder[,fileDLType])
引数名データ型内容値の事例初期値省略
objIEInternetExplorerIEオブジェクトobjIE,objIE2×
tagStrStringタグ内の一意のキーワード文字列"vbaproject"×
saveFolderStringファイル保存先のフォルダ文字列"image"×
fileDLTypeStringダウンロードするファイルの種類文字列"img",
"pfd",
"xls",
"doc"		"img"●

引数objIEは必須項目で、文書ドキュメントを抽出するnternetExplorerオブジェクトを指定します。InternetExplorerオブジェクトを引数に設定することで、複数のオブジェクトを処理することができます。

引数tagStrは必須項目で、抽出するタグ内の一意のキーワードを文字列で指定します。「抽出するタグ内の一意のキーワード」というのは、ダウンロードするファイルが設定されているタグ内で他とまったく被らないキーワードのことを指します。

例えば下記の場合、「こちらは一意のアンカーテキストです。」というキーワードは他では利用されていないキーワードですので、こちらを「一意のキーワード」と判断します。他にも「アンカーテキストです。」「です。」も一意のキーワードとして利用することもできます。

こちらの詳細については、「文書ドキュメント取得の処理の考え方」を確認してください。

<a href="#a1">こちらは一意のアンカーテキストではありません。</a>
<a href="#a2">こちらは一意のアンカーテキストではありません。</a>
<a href="#a3">こちらは一意のアンカーテキストです。</a>
<a href="#a4">こちらは一意のアンカーテキストではありません。</a>
<a href="#a5">こちらは一意のアンカーテキストではありません。</a>

引数saveFolderは必須項目で、ファイル保存先のフォルダ文字列を指定します。保存先は処理を実行するエクセルファイルと同じディレクトリで「saveFolder」で指定したフォルダ内に保存されます。

引数fileDLTypeは任意項目で、ファイルの種類を指定します。初期状態では「img」が設定されていますので、画像をダウンロードする場合は設定不要ですが、pdfファイルなど画像ファイル以外の場合は、拡張子でもなんでもいいので分かりやすいキーワードで指定してください。

こちらの引数fileDLTypeはファイルのURLを取得するための条件分岐で利用されます。「img」の場合はsrcValueサブルーチンでimg要素から画像URLを抽出し、そのほかの場合はlinkValueサブルーチンでa要素からファイルURLを抽出します。

  Dim fileURL As String, fileName As String, savePath As String
　Dim cacheDel As Long, result As Long

※ドラッグ(スワイプ)すると全体を確認できます。

こちらは、変数宣言でメモリ領域を割り当てるDimステートメントを利用してオブジェクト変数objIEにInternetExplorer型を、変数imgURL・fileName・savePathに「文字列型(String)」を、変数cacheDel・resultに「長整数型(Long)」を変数宣言しています。

URLDownloadToFile関数を利用する際によくあるトラブルが変数宣言の間違いです。戻り値の変数に整数型(Integer)を宣言している場合は「オーバーフローしました。」とエラーになります。理由としては、ダウンロードが失敗した場合の戻り値は「-2146697210 」となるため、整数型では許容範囲を超えるためです。

ですので、URLDownloadToFile関数とDeleteUrlCacheEntry関数の戻り値の変数には、長整数型を宣言しています。

If fileDLType = "img" Then
　fileURL = srcValue(objIE, tagStr)
Else
　fileURL = linkValue(objIE, tagStr)
End If

※ドラッグ(スワイプ)すると全体を確認できます。

こちらは引数fileDLTypeで指定されたファイルの種類を、条件分岐ができるIf～Then～Elseステートメントを利用してチェックしています。「img」の場合はsrcValueサブルーチンで画像URLを取得し、それ以外の場合はlinkValueサブルーチンでファイルURLを取得しています。

  'ファイルチェック
  If fileURL = "" Then
    MsgBox "ファイルURLを取得できませんでした。"
    Exit Sub
  End If

※ドラッグ(スワイプ)すると全体を確認できます。

こちらもIf～Then～Elseステートメントを利用してファイルURLが取得されているかどうかチェックを行い、取得できなかった場合はExit Subステートメントで処理を終了させています。

　'ファイル名
　fileName = Mid(fileURL, InStrRev(fileURL, "/") + 1)

※ドラッグ(スワイプ)すると全体を確認できます。

こちらはMid関数とInStrRev関数を利用してファイルURLからファイル名の部分だけを抽出しています。

InStrRev関数は文字列の中から指定した文字列が後ろから何番目にあるかを返す文字列処理関数です。指定した文字列は「/(スラッシュ)」になりますので、一番後ろの「/(スラッシュ)」の位置を返します。

Mid関数は文字列から指定した文字数分の文字列を返す関数です。画像ファイル名は、一番後ろの「/(スラッシュ)」の位置から右側部分になりますので、抽出開始位置は「/(スラッシュ)」の位置から「+1」としています。これにより画像ファイル名のみを抽出することができます。

そして、抽出したファイル名を変数fileNameに格納します。

'ファイル保存先(+画像ファイル名）
　savePath = ActiveWorkbook.Path & "\" & saveFolder & "\" & fileName

※ドラッグ(スワイプ)すると全体を確認できます。

こちらはファイルの保存先(+ファイル名）の設定ですが、実行ファイルと同じディレクトリにある変数saveFolderのフォルダへ格納します。こちらを利用する場合は事前にフォルダを作成する必要がありますので作成しておいてください。

また、こちらはURLDownloadToFile関数で利用する引数になりますが、同じ名前のファイルが存在したい場合は、上書き保存されますので注意が必要です。

cacheDel = DeleteUrlCacheEntry(fileURL)

※ドラッグ(スワイプ)すると全体を確認できます。

こちらはWindows APIのDeleteUrlCacheEntry関数を利用してキャッシュをクリアしています。引数には、変数fileURLを設定します。

こちらの処理はキャッシュがあった場合、古いファイルを誤ってダウンロードしてしまう可能性もあるため、ファイルをダウンロードする前に一旦キャッシュを削除しています。

result = URLDownloadToFile(0, fileURL, savePath, 0, 0)

※ドラッグ(スワイプ)すると全体を確認できます。

こちらはURLDownloadToFile関数を利用して画像をダウンロードする処理になります。引数はいくつかありますが、第二引数に「ファイルURL」を第三引数に「画像の保存先(+画像ファイル名）」を設定します。これでファイルをダウンロードすることができます。

If result <> 0 Then
　MsgBox "ダウンロードに失敗しました。"
End If

※ドラッグ(スワイプ)すると全体を確認できます。

こちらは正常にダウンロードされたかのチェック部分になります。URLDownloadToFile関数はダウンロードに成功すると「0」を返すので、If～Then～Elseステートメントを利用して変数resultが「0以外(ダウンロード失敗)」の場合は「ダウンロードに失敗しました。」と表示されます。

「fileDL」を利用して指定したファイルをダウンロードするサンプルコード

こちらのVBAコードは、fileDLサブルーチンを利用して指定したファイルをダウンロードするマクロです。

Sub sample()

  Dim objIE  As InternetExplorer

  'InternetExplorerでライブラリ追加ページを表示
  Call ieView(objIE, "http://www.vba-ie.net/library/index.html")
  
  'ファイルをダウンロードして保存
　Call fileDL(objIE, "vbaproject", "image")

End Sub

※ドラッグ(スワイプ)すると全体を確認できます。

ダウンロードするファイルのHTMLコード

<img src="/img/vbaproject.png" alt="VBAの参照設定" width="400" height="275" />

実行結果

URLDownloadToFileのダウンロード画像

解説

Sub sample()

  Dim objIE  As InternetExplorer

※ドラッグ(スワイプ)すると全体を確認できます。

こちらはSubステートメントに引数の設定がないsampleプロシージャになります。 まずは、Dimステートメントを利用してオブジェクト変数objIEに「InternetExplorer型」を変数宣言しています。

  'InternetExplorerでライブラリ追加ページを表示
  Call ieView(objIE, "http://www.vba-ie.net/library/index.html")

※ドラッグ(スワイプ)すると全体を確認できます。

次に他のプロシージャを呼び出すCallステートメントを利用してieViewサブルーチンを呼び出しています。第一引数にはオブジェクト変数の「objIE」を第二引数には表示させるURL(アドレス)の「http://www.vba-ie.net/library/index.html」を設定しています。これによりInternetExplorerで指定したページが表示されます。

'ファイルをダウンロードして保存
　Call fileDL(objIE, "vbaproject", "image")

※ドラッグ(スワイプ)すると全体を確認できます。

こちらは、Callステートメントを利用してfileDLサブルーチンを呼び出しています。第一引数にはオブジェクト変数の「objIE」を、第二引数にはファイル要素内の一意のキーワード「vbaproject」を、第三引数にはファイルの保存先「image」を設定しています。

これにより指定した画像ファイルを「image」フォルダへダウンロードします。今回は、画像ファイルですが、PDFファイルなど画像ファイル以外は第四引数に「pdf」「xls」などを設定してください。

まとめ

今回は、特定の画像ファイルやPDFファイルなどをダウンロードするサブルーチンの作成について解説していきます。こちらを利用してループ処理をすればファイルを一括ダウンロードすることも可能です。次回はtable要素の文書ドキュメントを取得する方法について解説していきます。

次の記事： エクセルVBAでtable要素の文書ドキュメントを取得する >>

Excel VBAでIEを思いのままに操作できるプログラミング術 Excel 2013/2010/2007/2003対応

IEのデータ収集＆自動操作のプログラミング本はこの1冊だけ！IEの起動やポップアップウィンドウ、表示を制御する基本的なコードはもちろん、テキストボックスやラジオボタン、表、ハイパーリンクなどのHTML部品を制御する方法など、自動操作に欠かせないノウハウを丁寧に解説。

VBAのIE制御についてのQ&A掲示板

↑VBAのIE操作で分からない事があればこちらの掲示板よりご質問ください。

ExcelのVBA初心者入門

↑こちらはVBAをマスターできるよう初心者向けのエクセルVBA入門コンテンツになります。

目次

IE制御の準備

IE制御の基本操作

IE制御の基本操作一覧(16)

HTMLエレメント基本操作

HTMLエレメント基本操作一覧(16)

HTMLエレメント実践操作

HTMLフォーム基本操作

HTMLフォーム基本操作一覧(16)

HTMLフレームの基本操作

HTMLフレームの基本操作一覧(8)

IE制御の応用編

IE制御の応用編一覧(7)

IE操作に便利なツール

こちらでは、これまでに紹介したIE(InternetExplorer)操作で便利な機能をツール化しています。無償でダウンロードできますので、目的に合わせたご利用ください。

IEのメソッド・プロパティ

こちらでは、IE(InternetExplorer)オブジェクトのメソッド・プロパティをまとめています。

IE操作のVBA関数

こちらでは、エクセルVBAのIE(InternetExplorer)操作で利用されたVBA関数をまとめています。

IE操作のステートメント

こちらでは、エクセルVBAのIE(InternetExplorer)操作で利用されたステートメントをまとめています。ExcelのVBAで基本的な部分になりますので、しっかり理解しましょう。

IE制御のVBAコード

こちらでは、これまでに作成したIE(InternetExplorer)操作で役立つサブルーチンをまとめています。
全てをコピーする必要はありませんが、目的に合わせたサブルーチンをご利用ください。

役立つVBAコード

役立つVBAコード一覧(23)

▲