エクセルVBAで2つのIEウィンドウを横並びにする

前回は、IEウィンドウの位置やサイズを設定する方法について解説してきました。IE(InternetExplorer)ウィンドウの位置やサイズなんて特に気にしないという方もいるかと思いますが、目的によっては必要な機能となります。

例えば2つのサイトの内容を比較したい場合、何も設定していないと重なって表示されてしまうため、毎回手動でIE(InternetExplorer)ウィンドウを移動しなければならず手間がかかります。

そのような時にAサイトとBサイトの表示位置を事前に設定し制御しておけば、簡単に比較することができます。今回は2つのIEウィンドウを横並びにする方法について解説していきます。

目次

• 2つのIE(InternetExplorer)ウィンドウを横に並べる処理の流れ
• 利用するサブルーチン・プロパティ・VBA関数について
  • ieViewサブルーチンとは
  • ieCheckサブルーチンとは
  • Topプロパティとは
  • Leftプロパティとは
  • Widthプロパティとは
  • Heightプロパティとは
  • FullScreenプロパティとは
  • Int関数とは
• 2つのIE(InternetExplorer)を横に並べるサンプルコード
  • 実行結果
  • 解説
• まとめ

2つのIE(InternetExplorer)を横に並べる処理の流れ

以下が今回の処理の流れになります。

• ①変数宣言
• ②ieViewサブルーチンを利用して本サイトをIEで起動
• ③IEウィンドウを最大化で表示
• ④最大化したIEウィンドウの幅・高さの値を取得
• ⑤IEウィンドウを標準サイズで表示
• ⑥IEウィンドウ(本サイト)の位置・サイズを設定
• ⑦ieViewサブルーチンを利用してyahooサイトをIEで起動
• ⑧IEウィンドウ(yahooサイト)の位置・サイズを設定

利用するサブルーチン・プロパティ・VBA関数について

今回利用するサブルーチン・プロパティ・VBA関数は以下になります。

ieViewサブルーチンとは

ieViewサブルーチンは指定したURLをInternetExplorerで起動させ、Webページが完全に読み込まれるまで待機処理をするマクロです。

ieCheckサブルーチンとは

ieCheckサブルーチンは指定したInternetExplorerオブジェクトのWebページが完全に読み込まれるまで待機処理をするマクロです。

Topプロパティとは

InternetExplorerオブジェクトのTopプロパティはディスプレイ画面の上端からIEウィンドウの上端までの距離の値を取得または設定をすることができます。基準はディスプレイ画面の左上からになります。また、単位はピクセル(1ピクセル=1/96インチ）になります。

Leftプロパティとは

InternetExplorerオブジェクトのLeftプロパティはディスプレイ画面の左端かIEウィンドウの左端までの距離の値を取得または設定をすることができます。基準はディスプレイ画面の左上からになります。また、単位はピクセル(1ピクセル=1/96インチ）になります。

Widthプロパティとは

InternetExplorerオブジェクトのWidthプロパティはIEウィンドウの幅の値を取得または設定をすることができます。また、単位はピクセル(1ピクセル=1/96インチ）になります。

Heightプロパティとは

InternetExplorerオブジェクトのHeightプロパティはIEウィンドウの高さの値を取得または設定をすることができます。また、単位はピクセル(1ピクセル=1/96インチ）になります。

FullScreenプロパティとは

InternetExplorerオブジェクトのFullScreenプロパティは、IEウィンドウを最大化し、アドレスバー・メニューバー・ツールバー・ステータスバーを非表示にします。

Int関数とは

Int関数とは、指定した数値または計算式の整数部分を返します。尚、小数部分がある場合は小数点以下を切り捨てた整数値を返します。

2つのIE(InternetExplorer)を横に並べるサンプルコード

2つのIE(InternetExplorer)を横に並べるマクロです。

Sub sample()

    Dim objIE As InternetExplorer, objIE2 As InternetExplorer
    Dim maxWidth As Integer, maxHeight As Integer, halfWidth As Integer
    
    '本サイトをIE(InternetExplorer)で起動
    Call ieView(objIE, "http://www.vba-ie.net/")
    
    'IEウィンドウの最大化
    objIE.Fullscreen = True
    
    maxWidth = objIE.Width  'IEウィンドウの最大幅
    maxHeight = objIE.Height    'IEウィンドウ最大高さ

    'IEウィンドウのサイズ標準
    objIE.Fullscreen = False
    
    halfWidth = Int(maxWidth / 2)

    With objIE
        .Top = 0
        .Left = 0
        .Width = halfWidth
        .Height = maxHeight
    End With
    
    'yahooサイトをIE(InternetExplorer)で起動
    Call ieView(objIE2, "http://yahoo.co.jp", , 0, halfWidth, halfWidth, maxHeight)

End Sub

実行結果

本サイトとyahooサイトが横並びで表示されます。

解説

Sub sample()

    Dim objIE As InternetExplorer, objIE2 As InternetExplorer
    Dim maxWidth As Integer, maxHeight As Integer, halfWidth As Integer

こちらはSubステートメントに引数の設定がないsampleプロシージャになります。 まずは、変数宣言でメモリ領域を割り当てるDimステートメントを利用してオブジェクト変数objIE,objIE2にInternetExplorer型を変数maxWidth,maxHeight,halfWidthに整数型(Integer)を変数宣言しています。

    '本サイトをIE(InternetExplorer)で起動
    Call ieView(objIE, "http://www.vba-ie.net/")

次に他のプロシージャを呼び出すCallステートメントを利用してieViewサブルーチンを呼び出しています。それぞれの第一引数にはオブジェクト変数の「objIE」を第二引数には表示させるURLの「http://www.vba-ie.net/」を設定しています。これにより本サイトがInternetExplorerで表示されます。

    'IEウィンドウの最大化
    objIE.Fullscreen = True

こちらはウィンドウ表示の設定でIEウィンドウを最大化させるInternetExplorerオブジェクトのFullscreenプロパティの値を「True」に設定するとIEウィンドウが最大化されます。これはIEウィンドウの最大化状態からディスプレイサイズを取得するための処理です。

    maxWidth = objIE.Width  'IEウィンドウの最大幅
    maxHeight = objIE.Height    'IEウィンドウ最大高さ

IEウィンドウの最大化状態からIEウィンドウの幅と高さを取得します。最大化した状態ですのでこちらの値が、ディスプレイのサイズとなります。変数maxWidthにはInternetExplorerオブジェクトのWidthプロパティを利用してIEウィンドウの幅サイズを、変数maxHeightにはInternetExplorerオブジェクトのHeightプロパティを利用してIEウィンドウの高さサイズを代入演算子で代入しています。尚、単位はピクセルになります。

    'IEウィンドウのサイズ標準
    objIE.Fullscreen = False

こちらでは再度InternetExplorerオブジェクトのFullscreenプロパティを利用して、IEウィンドウのサイズを標準に戻しています。後で横並びにするならわざわざ戻す必要もないのではという方もいらっしゃると思いますが、こちらはとても重要な処理です。

というのもIEウィンドウを最大化した状態からIEウィンドウの位置やサイズを設定することができないためです。IEウィンドウの位置やサイズを設定する場合はIEウィンドウの位置やサイズを変更できる標準の状態に戻す必要があります。

    halfWidth = Int(maxWidth / 2)

こちらは変数halfWidthにIEウィンドウ最大幅サイズの1/2の値を代入しています。今回は2つのIEウィンドウを横並びにするため、IEウィンドウの最大幅の1/2がそれぞれのIEウィンドウの幅になります。

右辺の処理はIEウィンドウの最大幅の値が格納されている変数maxWidthの値を算術演算子を利用して2で割っています。変数maxWidthの値はディスプレイのサイズですので、基本的に2で割ったとして整数値で取得できると思いますが、念のためInt関数を利用して整数値で取得してから変数halfWidthに代入しています。

少し話がそれますが、変数halfWidthは整数型(Integer)ですので、例え「maxWidth / 2」の値が小数点を含む値だったとしても四捨五入されて丸められます。それに対してInt関数は小数点を切り捨てますので、得られる値が異なります。

今回の場合は、数値の結果を求めているわけではないのでどちらでも構いませんが、数値を結果として求める場合は、理解したうえでVBA関数を利用するようにしましょう。今回利用したのは切り捨てられた値の方が確実にディスプレイ内に収まるであろう程度の話で利用しています。

    With objIE
        .Top = 0
        .Left = 0
        .Width = halfWidth
        .Height = maxHeight
    End With

こちらでは、1つのオブジェクトに対して処理をまとめるWithステートメントのオブジェクト名に「objIE」を設定しています。こちらはInternetExplorerオブジェクトになりますので、Withステートメント内では、オブジェクト名を省略して記述することができます。

次に、InternetExplorerオブジェクトの「Topプロパティ」「Leftプロパティ」「Widthプロパティ」「Heightプロパティ」に値を設定しています。IEウィンドウの幅サイズは先ほど取得した変数halfWidthの値を、高さサイズは最大化状態で取得したmaxHeightの値を設定しています。これによりディスプレイを2分割にした左側一面にIEウィンドウが表示されました。

    'yahooサイトをIE(InternetExplorer)で起動
    Call ieView(objIE2, "http://yahoo.co.jp", , 0, halfWidth, halfWidth, maxHeight)

End Sub

こちらはCallステートメントを利用してieViewサブルーチンを呼び出しています。第一引数にはオブジェクト変数の「objIE2」を、第二引数には表示させるURLの「http://yahoo.co.jp」を、第三引数は省略して設定しています。

次に第四～第七引数にはIEウィンドウの位置とサイズの値が設定されています。オブジェクト変数objIE2のIEウィンドウの位置はディスプレイを2分割にした右側に配置されますので、IEウィンドウのX位置は2分割した位置になる「変数halfWidth」が設定されています。

IEウィンドウのサイズについては左側のIEウィンドウと同じですので、それぞれ「変数halfWidth」と「変数maxHeight」を設定しています。これで、2つのIEウィンドウを横並びにすることができました。

最後は、Endステートメントを利用してプロシージャを終了させます。

まとめ

今回は、2つのIEウィンドウを横並びにする方法について解説してきました。縦並びにする場合も同様の処理になりますので、チャレンジしてみてください。次回はIE(InternetExplorer)でなく、ExcelウィンドウとIE(InternetExplorer)ウィンドウを横並びにする方法について解説していきます。こちらは今回の処理では対応できません。そのポイントとなるのが「単位」です。是非そちらも確認してください。

よく読まれているVBAのIE(InternetExplorer)操作関連記事

• 指定したURLをIE(InternetExplorer)で起動する
• InternetExplorer制御の準備（ライブラリ追加）
• HTMLドキュメント(全ての要素)を取得する
• HTMLDocumentのallオブジェクト
• webページのBasic認証自動ログイン「ieBasic」